Prev: 63861 Up: Map Next: 63898
63878: Check for the presence of a plant pot
Used by the routines at 23907 and 64077. Returns with the zero flag set if either ERIC or the recently ejected contents of the water pistol are on top of a plant pot:
Location Plant pot
91,2 Near the top-floor window
93,9 Near the middle-floor window
132,16 To the left of the skool gate
135,16 To the right of the skool gate
Input
H 210 (ERIC) or 214 (water/sherry)
63878 LD DE,40956 Point DE at the plant-pot y-coordinate table at 40956
63881 LD L,2 Point HL at byte 2 of the character's buffer
63883 LD A,(DE) A=y-coordinate of the plant pot
63884 CP (HL) Does this match the character's y-coordinate?
63885 JR NZ,63893 Jump if not
63887 DEC L L=1
63888 DEC D Point DE at the plant-pot x-coordinate table at 40700
63889 LD A,(DE) A=x-coordinate of the plant pot
63890 CP (HL) Does this match the character's x-coordinate?
63891 RET Z Return with the zero flag set if so
63892 INC D Point DE back at the plant-pot y-coordinate table
63893 INC E Next plant pot
63894 JR NZ,63881 Jump back until all four plant pots have been checked
63896 INC E Reset the zero flag to indicate the lack of any plant pot here
63897 RET
Prev: 63861 Up: Map Next: 63898