| Routines

30208: Write a character's name into the lines bubble graphic buffer

Used by the routine at 30464. Generates the graphic data for the text of the lines recipient's name (e.g. 'ERIC') and stores it in the buffer at 60160.
Input
A | Lines recipient's character number (167-169, 172)
30208 | LD BC,6167 | B=24; C=23 (INK 7: PAPER 2)
30211 | LD HL,60160 | The lines bubble graphic is stored at 60160
30214 | LD DE,55680 | 55680: 'ERIC'
30217 | CP 172 | Is ERIC being given lines?
30219 | JR Z,30238 | Jump if so
30221 | LD C,31 | 31=INK 7: PAPER 3
30223 | LD E,142 | DE=55694: 'BOY WANDER'
30225 | SUB 167 | Is BOY WANDER being given lines?
30227 | JR Z,30238 | Jump if so
30229 | LD C,39 | 39=INK 7: PAPER 4
30231 | LD E,156 | DE=55708: 'ANGELFACE'
30233 | DEC A | Is ANGELFACE being given lines?
30234 | JR Z,30238 | Jump if so
30236 | LD E,170 | DE=55722: 'EINSTEIN'
30238 | LD (HL),C | Fill in the appropriate attribute bytes for the lines bubble
30239 | INC L
30240 | DJNZ 30238
30242 | LD L,120 | HL=60280
30244 | EX DE,HL | DE=60280, HL=address of character name
This entry point is used by the routine at 63829.
30245 | CALL 30042 | Write the message into the graphic buffer
30248 | JP 30132 | Draw the left and right edges of the bubble